#########################################################################
#
# makesess - easy generation of all session feedback files
#
# USAGE: makesess
#    or: makesess <sessioncode (mmmyy)> <modified block schedule>
#
# It uses a stripped ascii version of the EVN network block schedule
# for an example see: /users/www/jive/evn/session/template/block4_97
#
# DO NOT USE AN UNDERSCORE IN THE BLOCK SCHEDULE (script will crash)
#               ^^^^^^^^^^
#-----------------------------------------------------------------------#
# Lorant 05/11/97
# Some modifications by Z.P. on 21 Oct 2002
#-----------------------------------------------------------------------#
#########################################################################

# define some directories, template files and initialisation thingies

set EVNROOT = /www/evlbi.org           

if ($#argv < 2) then
 echo ">> Didn't get all info wanted, so please help me out <<"
 echo " enter session abbriviation (mmmyy) "
 set mmmyy = $<
 echo " where is the (modified!) ascii block schedule? "
 echo "(for an example see template/block4_97, no TABs)"
 set block = $<
else # user is an expert
 set mmmyy = $argv[1]
 set block = $argv[2]
endif

set EVNSESS = $EVNROOT/session
set SESNAME = $EVNSESS/$mmmyy
set EVNTMPL = $EVNSESS/template
set wavel = $EVNTMPL/wavetmpl.hdr
set sessn = $EVNTMPL/sesstmpl.hdr
set newfr = $EVNTMPL/parttmpl.hdr
set entry = $EVNTMPL/ntrytmpl.hdr
set exhdr = $EVNTMPL/expttmpl.hdr

set flag = true

# make directory for session and define some session thingies

  if (-e $SESNAME) then
    repeat 18 printf "\a"
    printf "\nREMOVING THE OLD $SESNAME FIRST\n\n"
    rm -i -r $SESNAME
  endif
  mkdir $SESNAME

  @ sesno      = `grep -i session $block|cut -f1 -d'/'|cut -f3 -d'N'`
  set htmlfile = $SESNAME/$mmmyy.html
  set sesmonth = `echo $mmmyy:u|cut -c 1-3`
  @ sesyear    = 20`echo $mmmyy|cut -c 4,5`
  set sesnme   = `echo $sesmonth $sesyear`

# which wavelengths and projects (in order of appearance)

  set cmlist = `grep Part $block|cut -f4 -d" "`
  set exlist = `grep -v Part $block|grep -v '='|grep -vi session|cut -c 17-23`

# copy header file for individual wavelengths and the whole session

#  foreach wave ($cmlist)
#    cat $wavel|sed s_mmmyy_${mmmyy}_g|sed s_monthyear_"$sesnme"_g \
#              |sed s_iiiii_${sesno}_g|sed s_lllll_"$wave"_g \
#              > $SESNAME/"$wave"cm.hdr   
#  end
  cat $sessn|sed s_mmmyy_${mmmyy}_g|sed s_monthyear_"$sesnme"_g \
            |sed s_iiiii_${sesno}_g|sed s_alalalalal_"$cmlist"_g \
            > $SESNAME/allsession.hdr
  ln -s $SESNAME/allsession.hdr $SESNAME/allsession.html

# copy header of general project summary file

  cat $EVNTMPL/headtmpl.hdr|sed s_mmmyy_${mmmyy}_g|sed s_iiiii_${sesno}_g \
                           |sed s_monthyear_"$sesnme"_g > $htmlfile
  set lab0 = 0
  echo " "
  echo "Experiments during EVN session $sesno $sesyear; $sesnme ($mmmyy)"
  echo "#######################################################"

# scan the projects and define project thingies

  foreach proj ($exlist)
    set lab    = `grep $proj $block|cut -c -4`
    set piname = `grep $proj $block|cut -c 5-16`
    set titles = "`grep $proj $block|cut -c 24-99`"
    set expt   = `echo $proj:agl`
    set caps   = `echo $proj:agu`
    echo "Doing $lab cm; PI: $piname ($proj) $titles"

# start a new wavelength band? (then add a wavelength header)

    if ( "$lab" != "$lab0" ) then
      if ("$flag" == 'false') echo "</TABLE>" >> $htmlfile
      set flag = 'true'
      set lab0 = $lab
      if ( "$lab" != "$lab0" ) exit 1
      cat $newfr|sed s_mmmyy_${mmmyy}_g|sed s_lllll_"$lab0"_g >> $htmlfile
    endif

# add this expt to general project summary file

    cat $entry|sed s_mmmyy_${mmmyy}_g|sed s_pipipipipi_"$piname"_g \
              |sed s_EEEEE_"$caps"_g |sed s_eeeee_${expt}_g \
              |sed s_ttttt_"$titles"_g >> $htmlfile

# make seperate expt header file

    cat $exhdr|sed s_mmmyy_${mmmyy}_g|sed s_monthyear_"$sesnme"_g \
              |sed s_iiiii_${sesno}_g|sed s_lllll_"$lab0"_g \
              |sed s_EEEEE_${caps}_g |sed s_eeeee_${expt}_g \
              > $SESNAME/$expt.hdr
    ln -s $SESNAME/$expt.hdr $SESNAME/$expt.html
 
#    echo "Done $proj"
     set flag = 'false'
    shift proj
  end

# copy tail of general project summary file

  echo "</TABLE>" >> $htmlfile
  cat $EVNTMPL/foottmpl.hdr >> $htmlfile

# tie up loose ends

  cp $EVNSESS/arrow2d.gif $SESNAME
  printf "\a"
  chmod 777 $SESNAME ; chmod 666 $SESNAME/*.hdr ; chmod 644 $htmlfile 
  echo " "
  echo "Done setting up $SESNAME; Have fun experimenting"
  printf "\a"
  echo " "

exit